You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.

70 lines
2.5 KiB

# Maintainer: Johannes Löthberg <johannes@kyriasis.com>
# Contributor: Ivan Shapovalov <intelfx@intelfx.name>
pkgname=matrix-synapse
pkgver=1.33.1
pkgrel=1
pkgdesc="Matrix reference homeserver"
url="https://github.com/matrix-org/synapse"
arch=('any')
license=('Apache')
depends=('libwebp' 'python-jsonschema' 'python-twisted'
'python-pyopenssl' 'python-yaml' 'python-pyasn1' 'python-pynacl'
'python-bcrypt' 'python-frozendict'
'python-pillow' 'python-ujson'
'python-pysaml2' 'python-setuptools'
'python-systemd' 'python-unpaddedbase64' 'python-canonicaljson'
'python-signedjson' 'python-pymacaroons'
'python-service-identity' 'python-msgpack'
'python-phonenumbers' 'python-prometheus_client'
'python-attrs' 'python-netaddr' 'python-sortedcontainers'
'python-treq' 'python-idna' 'python-jinja'
'python-bleach' 'python-typing_extensions' 'systemd')
checkdepends=('python-authlib' 'python-pyjwt' 'python-lxml' 'python-mock' 'python-parameterized'
'python-txredisapi' 'python-hiredis')
optdepends=('perl: sync_room_to_group.pl'
'python-psycopg2: PostgreSQL support'
'python-lxml: URL previewing'
'python-psutil: metrics'
'python-pyjwt: jwt'
'python-txredisapi: redis'
'python-hiredis')
source=("synapse-$pkgver.tar.gz::https://github.com/matrix-org/synapse/archive/v$pkgver.tar.gz"
'synapse.service'
'sysusers-synapse.conf'
'tmpfiles-synapse.conf')
sha256sums=('fd074ebcb443d28989c0f49e50c4f27bc6d0fe6b454923a9df67be5951b01b16'
'ce434eaa92e6504988fb9005d49c078ab7a2d33951d8adece26ccce8b2475857'
'aadfdd78fe73e6eb325ee4299b8db8b97bfa2f4e7df953aa8477f442598a7ec5'
'65588c8c64dfb84cab831cd8d028a295d753cf7322dd63053e8488466047b45f')
backup=('etc/synapse/log_config.yaml')
install=synapse.install
build() {
cd synapse-$pkgver
python setup.py build
}
check() {
cd synapse-$pkgver
PYTHONPATH=. trial tests
}
package() {
install -Dm644 synapse.service "$pkgdir"/usr/lib/systemd/system/synapse.service
cd synapse-$pkgver
export PYTHONHASHSEED=0
python setup.py install --root "$pkgdir" --optimize=1 --skip-build
install -dm755 -o 198 -g 198 "$pkgdir"/etc/synapse
install -Dm644 contrib/systemd/log_config.yaml "$pkgdir"/etc/synapse/log_config.yaml
install -Dm644 "$srcdir"/sysusers-synapse.conf "$pkgdir"/usr/lib/sysusers.d/synapse.conf
install -Dm644 "$srcdir"/tmpfiles-synapse.conf "$pkgdir"/usr/lib/tmpfiles.d/synapse.conf
}